Ayuda ok comprobar base datos

[PILO]

Necesito ayuda para lo siguiente
en el ejemplo de xailer
C:xailerSamplesDataControlsDBFData2
cuando doy un alta nuevo
y ya he puesto los datos en el Form2
Cuando pulse el boton OK quiero comprobar
por el indice FIRST si el nombre puesto
en el TDBEdit oFirst ixiste en la base de datos
Si exite tiene que volver a el TDBEdit oFirst
para poner otro
Alquien me puede poner un pequeño ejemplo
Gracias a todos
--

[jrcpoli-quitar]

PILO escribió:
> *Necesito ayuda para lo siguiente*
> en el ejemplo de xailer
> C:xailerSamplesDataControlsDBFData2
> cuando doy un alta nuevo
> y ya he puesto los datos en el Form2
> Cuando pulse el boton OK quiero comprobar
> por el indice FIRST si el nombre puesto
> en el TDBEdit oFirst ixiste en la base de datos
> Si exite tiene que volver a el TDBEdit oFirst
> para poner otro
>
> Alquien me puede poner un pequeño ejemplo
> Gracias a todos
Puedes hacerlo de dos formas una es capturando el evento OnExit cuando
salgas del campo, comprobando que el valor introducido en el mismo ya
existe en la base de datos.
METHOD FirstExit( oSender, oNextCtl ) CLASS TForm2
LOCAL lCorrecto := Nil
** Estamos en proceso de alta
IF ::oParent:oDataSet:lOnAppend
*
** Comprobamos que el campo no este vacio
IF !Empty(oSender:Value)
** Guardamos el estado de la base de datos
::oParent:oDataSet:SaveState( .T. )
** Seleccionamos el orden
::oParent:oDataSet:OrdSetFocus("FIRST")
IF ::oParent:oDataSet:Seek(Alltrim(oSender:Value))
MsgAlert("¡ El registro Existe ! " )
lCorrecto := .F.
ELSE
lCorrecto := .T.
ENDIF
** Restauramos el estado de la base de datos
::oParent:oDataSet:RestoreState( .T. )
ELSE
MsgInfo("¡ Este campo no puede estar vacio !")
lCorrecto := .F.
ENDIF
*
ENDIF
RETURN lCorrecto
y una segunda formula es capturando en evento OnClick del botón OK del
formulario que controla si se cierra o no el formulario, en tu caso si
el valor del campo está repetido mandas que el formulario no se cierre y
activas el foco sobre el campo del error.
METHOD OKClick( oSender ) CLASS TForm2
LOCAL lCorrecto := Nil
** Estamos en proceso de alta
IF ::oParent:oDataSet:lOnAppend
*
IF !Empty(::oFirst:Value)
** Guardamos el estado de la base de datos
::oParent:oDataSet:SaveState( .T. )
** Seleccionamos el orden
::oParent:oDataSet:OrdSetFocus("FIRST")
IF ::oParent:oDataSet:Seek(Alltrim(::oFirst:Value))
MsgAlert("¡ El registro Existe ! " )
::oFirst:SetFocus()
lCorrecto := .F.
ELSE
lCorrecto := .T.
ENDIF
** Restauramos el estado de la base de datos
::oParent:oDataSet:RestoreState( .T. )
ELSE
MsgInfo("¡ Este campo no puede estar vacio !")
::oFirst:SetFocus()
lCorrecto := .F.
ENDIF
*
ENDIF
RETURN lCorrecto
Me queda un pequeño detalle pero importante en el botón Cancelar del
formulario dos la propiedad lCancel pon la a .T. para que no te evalue
el evento OnExit al salir si empleas el método primero.
Espero no haberme equivocado, y como siempre digo dos no harán lo mismo
de la misma forma.
Mira todos los eventos y comandos en la Ayuda para que se te quedes con
ellos es importante que lo hagas.
José Ramón Castro