Xailer & OZ Software

Tengo un TDBEditBtn. cuando precinoo el buton mando llamar una forma con un
browse
Pero no he podido hacer que se actualice el TDBEeditBtn con el registro
selecctionado en el Browse.
¿Como lo hago?
Gracias.

Saludos:
Una forma de hacerlo es esta, siempre que el DataSet este en modo Editar
o Añadir.
** Llamada al evento que se produce al pulsar el icono
** del TDBEditBtn
METHOD Buscar_ConcClick( oSender ) CLASS TFormIndiv
*
WITH OBJECT TVerSocios():New( Self )
:ShowModal()
IF :nModalResult == mrOK
::oN_Conc:Value := :DNumero
::oNombre_Conc:Value := :DNombre
ENDIF
:END()
END
*
RETURN Nil
/*
* Proyecto: Concurso
* Fichero: VerSocios.prg
* Descripción:
* Autor:
* Fecha: 15/10/2005
*/
#include "Xailer.ch"
** TFormVer es un formulario común para varios prg.
** TVerSocios es un prg solo que contiene la llamada a los controles de
TFormVer
CLASS TVerSocios FROM TFormVer
METHOD FormInitialize( oSender )
METHOD Ok()
ENDCLASS
//---------------------------------------------------------- --------------------
METHOD FormInitialize( oSender ) CLASS TVerSocios
oSender:cText := "Seleccione Concursante"
*
** Inicializamos la base de datos
WITH OBJECT ::oDataSet
:cName := 'CONCURSA.DBF'
:lOpen := .T.
END
*
** Si la apertura es correcta
IF ::oDataSet:lOpen
*
** Cargar el orden en el formulario
::oComboOrden:aItems := ::oDataSet:GetTags()
*
** Orden del Formulario
::oDataSet:OrdSetFocus(::oComboOrden:GetText())
*
** Browse
WITH OBJECT ::oBrowseVer
*
// Aqui se configuran las columnas
// del Browse
WITH OBJECT TDBBrwColumn():New( ::oBrowseVer )
:cHeader := "Nº Conc."
:nWidth := 57
:oDataField := "NUM_CONC"
:Create()
END
WITH OBJECT TDBBrwColumn():New( ::oBrowseVer )
:cHeader := "Lic.Nacional"
:nWidth := 60
:oDataField := "LIC_NAC"
:Create()
END
WITH OBJECT TDBBrwColumn():New( ::oBrowseVer )
:cHeader := "Nombre Concursante "
:nWidth := 200
:oDataField := "NOMBRE_CON"
:Create()
END
WITH OBJECT TDBBrwColumn():New( ::oBrowseVer)
:cHeader := "Nº Club "
:nWidth := 60
:oDataField := "NUM_CLUB"
:Create()
END
WITH OBJECT TDBBrwColumn():New( ::oBrowseVer )
:cHeader := "Nº Federac. "
:nWidth := 60
:oDataField := "N_FED"
:Create()
END
WITH OBJECT TDBBrwColumn():New( ::oBrowseVer )
:cHeader := "Nº Zona "
:nWidth := 60
:oDataField := "N_ZONA"
:Create()
END
*
:oDataSet := ::oDataSet
*
END
ENDIF
*
RETURN Super:FormInitialize( oSender )
//---------------------------------------------------------- --------------------
METHOD Ok() CLASS TVerSocios
IF ::oBrowseVer != NIL
::DNombre := ::oDataSet:FieldGetByName( "NOMBRE_CON" )
::DNumero := ::oDataSet:FieldGetByName( "NUM_CONC" )
ENDIF
RETURN Nil
José Ramón Castro.
Edgar A. Barrera Cardenas escribió:
> Tengo un TDBEditBtn. cuando precinoo el buton mando llamar una forma con un
> browse
>
> Pero no he podido hacer que se actualice el TDBEeditBtn con el registro
> selecctionado en el Browse.
>
>
> ¿Como lo hago?
>
> Gracias.
>
>