Xailer forum

Código: Seleccionar todo

   with object oCtrl

      if :isKindOf('TLabelBuddy')

         oInspector:setControl(oCtrl)
         :cText:=Value

         //oInspector:setControl(oInspector:oActiveForm)
         //oInspector:setControl(oCtrl)
         //oPlugin:IEditor:lModified:=.t.
         oInspector:Refresh()
         
      //elseif :isKindOf('TLabel')

      endif

   end with

Código: Seleccionar todo

/*
 * Proyecto: ControlsInitProps
 * Fichero: Main.prg
 * Descripción:
 * Autor:
 * Fecha: 14/01/2021
 */

#include "Xailer.ch"

#define TOOLTIP_ICONINFO        2266

DYNAMIC TIDEPlugin
memvar oInspector, oCode

//------------------------------------------------------------------------------

INIT PROC CIP_PluginRegister()

   WITH OBJECT TCIP_PlugIn():New()
      :cName := "ICIP_Plugin"
      :cDescription := "Valores iniciales de controles"
      :cVersion := "1.2"
      :cCategory := "Samples"
      :cImage := "ICIP_Plugin"
      :Install()
   END

RETURN

//------------------------------------------------------------------------------

CLASS TCIP_Plugin FROM TIDEPlugin

   DATA oMenuItem
   DATA oRunProject
   DATA oRunForm
   DATA cRunProjectName

   METHOD Install()
   METHOD GetInfo()
   METHOD Config()
   METHOD Run( oControl, aSelection )
   METHOD SaveState()
   METHOD LoadState()

ENDCLASS

//------------------------------------------------------------------------------

METHOD Run( oControl, aSelection )

   local lMod := .f.

   if oControl == NIL .OR. !::oMenuItem:lChecked
      return nil
   endif

   ::oRunForm        := oControl:oForm
   ::oRunProject     := NIL
   ::cRunProjectName := ""

   IF ::oRunForm != NIL
      ::oRunProject := ::oRunForm:oProject
      IF ::oRunProject != NIL
         ::cRunProjectName := ::oRunProject:cName
      endif
   ENDIF

   WITH OBJECT oControl
      IF :IsKindOf( "TLabel" )
         :cText := "My label" <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< WORKING
         // We do nothing since lAutoSize should be enough
//         :nHeight := 20
         lMod := .T.
      ELSEIF :IsKindOf( "TEditMod" )
         // No hacer nada. Lo ponemos para que no salte la siguiente
      ELSEIF :IsKindOf( "TEdit" )
         :nHeight := 22
         lMod := .T.
      ELSEIF :IsKindOf( "TButton" )
         :nHeight := 30
         :nWidth  := 90
         lMod := .T.
      ELSEIF :IsKindOf( "TCheckBox" )
         :nHeight := 20
         lMod := .T.
      ELSEIF :IsKindOf( "TBrowse" )
         :nHeaderHeight := 30
         lMod := .T.
      ENDIF
   end with

   if lMod
      oInspector:SetControl( oControl )
      oCode:oOutputArea:NewTab( Lt( TOOLTIP_ICONINFO ), .F. ):Append( ;
        "Control modified by Plugin 'Controls Init'" + CRLF, 2 )
   ENDIF

return nil

//------------------------------------------------------------------------------

METHOD Install() CLASS TCIP_Plugin

   LOCAL oMenu := ::GetMainMenu():GetToolsMenu()

   ::RegisterMenuItem( oMenu:AddSeparator() )

   WITH OBJECT ::oMenuItem := TMenuItem():Create( oMenu, , , "Plugin: Controls Init Properties" )
      :OnClick := {|| ::Config() }
   END WITH

   ::LoadState()

   ::RegisterMenuItem( ::oMenuItem )

   ::cDescription := "Valores iniciales de controles"
   ::RegisterEvent( "FE_AddControl", {| oCtl, aSel | ::Run( oCtl, aSel ) } )
   ::Register()

RETURN Nil

//------------------------------------------------------------------------------

METHOD Config() CLASS TCIP_Plugin

   ::oMenuItem:lChecked := !::oMenuItem:lChecked
   ::SaveState()

return nil

//------------------------------------------------------------------------------

METHOD GetInfo() CLASS TCIP_Plugin

   LOCAL cInfo := "<b>Controls Init Properties</b>" + CRLF + ;
                  CRLF + ;
                  "Inicialización automática de ciertas propiedades de controles "+ ;
                  "cuando se añaden al formulario. Sólo configurable por código." + ;
                  + CRLF + CRLF + ;
                  "<b>Autor</b>: Ignacio Ortiz de Zúñiga" + CRLF + ;
                  "<b>Versión</b>: " + ::cVersion + CRLF + ;
                  "<b>Copyright</b>: 2021 Ignacio Ortiz de Zúñiga & Xailer"

RETURN cInfo

//------------------------------------------------------------------------------

METHOD LoadState() CLASS TCIP_Plugin

   LOCAL lState

   with object TIni():New( Application:cDirectory + "Xailer.cfg" )
      lState := :GetEntry( "PLUGINS", "ControlsInitPropertiesState", .F. )
      :End()
   END WITH

   ::oMenuItem:lChecked := lState

RETURN lState

//------------------------------------------------------------------------------

METHOD SaveState() CLASS TCIP_Plugin

   LOCAL lState := ::oMenuItem:lChecked

   with object TIni():New( Application:cDirectory + "Xailer.cfg" )
      :SetEntry( "PLUGINS", "ControlsInitPropertiesState", lState )
      :End()
   END WITH

RETURN lState

//------------------------------------------------------------------------------